Rules for integrands involving inverse hyperbolic sines

1.  ∫u(((a+b ArcSinh[c+d x]))^n)dx

1:  ∫(((a+b ArcSinh[c+d x]))^n)dx

Derivation: Integration by substitution

Rule:

∫(((a+b ArcSinh[c+d x]))^n)dx  ⟶  (1/d) Subst[∫(((a+b ArcSinh[x]))^n)dx,x,c+d x]

Program code:

Int[(a_.+b_.*ArcSinh[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[(a+b*ArcSinh[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,n},x]

2:  ∫(((e+f x))^m)(((a+b ArcSinh[c+d x]))^n)dx

Derivation: Integration by substitution

Rule:

∫(((e+f x))^m)(((a+b ArcSinh[c+d x]))^n)dx  ⟶  (1/d)Subst[∫(((((d e-c f)/d)+((f x)/d)))^m)(((a+b ArcSinh[x]))^n)dx,x,c+d x]

Program code:

Int[(e_.+f_.*x_)^m_.*(a_.+b_.*ArcSinh[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(a+b*ArcSinh[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,m,n},x]

3:  ∫(((A+B x+C (x^2)))^p)(((a+b ArcSinh[c+d x]))^n)dx  when  B (1+(c^2))-2 A c d==0 ∧ 2 c C-B d==0

Derivation: Integration by substitution

Basis: If  B (1+(c^2))-2 A c d==0 ∧ 2 c C-B d==0, then A+B x+C (x^2)==(C/(d^2))+(C/(d^2))(((c+d x))^2)

Rule: If  B (1+(c^2))-2 A c d==0 ∧ 2 c C-B d==0, then

∫(((A+B x+C (x^2)))^p)(((a+b ArcSinh[c+d x]))^n)dx  ⟶  (1/d)Subst[∫((((C/(d^2))+((C (x^2))/(d^2))))^p)(((a+b ArcSinh[x]))^n)dx,x,c+d x]

Program code:

Int[(A_.+B_.*x_+C_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[(C/d^2+C/d^2*x^2)^p*(a+b*ArcSinh[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,A,B,C,n,p},x] && EqQ[B*(1+c^2)-2*A*c*d,0] && EqQ[2*c*C-B*d,0]

4:  ∫(((e+f x))^m)(((A+B x+C (x^2)))^p)(((a+b ArcSinh[c+d x]))^n)dx  when  B (1+(c^2))-2 A c d==0 ∧ 2 c C-B d==0

Derivation: Integration by substitution

Basis: If  B (1+(c^2))-2 A c d==0 ∧ 2 c C-B d==0, then A+B x+C (x^2)==(C/(d^2))+(C/(d^2))(((c+d x))^2)

Rule: If  B (1+(c^2))-2 A c d==0 ∧ 2 c C-B d==0, then

∫(((e+f x))^m)(((A+B x+C (x^2)))^p)(((a+b ArcSinh[c+d x]))^n)dx  ⟶  (1/d)Subst[∫(((((d e-c f)/d)+((f x)/d)))^m)((((C/(d^2))+((C (x^2))/(d^2))))^p)(((a+b ArcSinh[x]))^n)dx,x,c+d x]

Program code:

Int[(e_.+f_.*x_)^m_.*(A_.+B_.*x_+C_.*x_^2)^p_.*(a_.+b_.*ArcSinh[c_+d_.*x_])^n_.,x_Symbol] :=
  1/d*Subst[Int[((d*e-c*f)/d+f*x/d)^m*(C/d^2+C/d^2*x^2)^p*(a+b*ArcSinh[x])^n,x],x,c+d*x] /;
FreeQ[{a,b,c,d,e,f,A,B,C,m,n,p},x] && EqQ[B*(1+c^2)-2*A*c*d,0] && EqQ[2*c*C-B*d,0]

2.  ∫(((a+b ArcSinh[c+d (x^2)]))^n)dx  when  (c^2)==-1

1.  ∫(((a+b ArcSinh[c+d (x^2)]))^n)dx  when  (c^2)==-1 ∧ n>0

1:  ∫(Sqrt[a+b ArcSinh[c+d (x^2)]])dx  when  (c^2)==-1

Derivation: Integration by parts

Note: This antiderivative is probably better expressed in terms of error functions...

Rule: If  (c^2)==-1, then

∫(Sqrt[a+b ArcSinh[c+d (x^2)]])dx  ⟶  x (Sqrt[a+b ArcSinh[c+d (x^2)]])-b d∫((x^2)/((Sqrt[2 c d (x^2)+(d^2) (x^4)]) (Sqrt[a+b ArcSinh[c+d (x^2)]])))dx

  ⟶  x (Sqrt[a+b ArcSinh[c+d (x^2)]])-
(((Sqrt[π]) x (Cosh[(a/(2 b))]-c Sinh[(a/(2 b))])FresnelC[(Sqrt[-(c/(π b))]) (Sqrt[a+b ArcSinh[c+d (x^2)]])])/((Sqrt[-(c/b)]) (Cosh[(1/2) ArcSinh[c+d (x^2)]]+c Sinh[(1/2) ArcSinh[c+d (x^2)]])))+
(((Sqrt[π]) x (Cosh[(a/(2 b))]+c Sinh[(a/(2 b))])FresnelS[(Sqrt[-(c/(π b))]) (Sqrt[a+b ArcSinh[c+d (x^2)]])])/((Sqrt[-(c/b)]) (Cosh[(1/2) ArcSinh[c+d (x^2)]]+c Sinh[(1/2) ArcSinh[c+d (x^2)]])))

Program code:

Int[Sqrt[a_.+b_.*ArcSinh[c_+d_.*x_^2]],x_Symbol] :=
  x*Sqrt[a+b*ArcSinh[c+d*x^2]] - 
  Sqrt[Pi]*x*(Cosh[a/(2*b)]-c*Sinh[a/(2*b)])*FresnelC[Sqrt[-c/(Pi*b)]*Sqrt[a+b*ArcSinh[c+d*x^2]]]/
    (Sqrt[-(c/b)]*(Cosh[ArcSinh[c+d*x^2]/2]+c*Sinh[ArcSinh[c+d*x^2]/2])) + 
  Sqrt[Pi]*x*(Cosh[a/(2*b)]+c*Sinh[a/(2*b)])*FresnelS[Sqrt[-c/(Pi*b)]*Sqrt[a+b*ArcSinh[c+d*x^2]]]/
    (Sqrt[-(c/b)]*(Cosh[ArcSinh[c+d*x^2]/2]+c*Sinh[ArcSinh[c+d*x^2]/2])) /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,-1]

2:  ∫(((a+b ArcSinh[c+d (x^2)]))^n)dx  when  (c^2)==-1 ∧ n>1

Derivation: Integration by parts twice

Basis: If  (c^2)==-1, then (∂_x)(((a+b ArcSinh[c+d (x^2)]))^n)==((2 b d n x (((a+b ArcSinh[c+d (x^2)]))^(n-1)))/(Sqrt[2 c d (x^2)+(d^2) (x^4)]))

Basis: ((x^2)/(Sqrt[2 c d (x^2)+(d^2) (x^4)]))==(∂_x)((Sqrt[2 c d (x^2)+(d^2) (x^4)])/((d^2) x))

Rule: If  (c^2)==-1 ∧ n>1, then

∫(((a+b ArcSinh[c+d (x^2)]))^n)dx  ⟶  x (((a+b ArcSinh[c+d (x^2)]))^n)-2 b d n∫(((x^2) (((a+b ArcSinh[c+d (x^2)]))^(n-1)))/(Sqrt[2 c d (x^2)+(d^2) (x^4)]))dx

  ⟶  x (((a+b ArcSinh[c+d (x^2)]))^n)-((2 b n (Sqrt[2 c d (x^2)+(d^2) (x^4)]) (((a+b ArcSinh[c+d (x^2)]))^(n-1)))/(d x))+4 (b^2)n (n-1)∫(((a+b ArcSinh[c+d (x^2)]))^(n-2))dx

Program code:

Int[(a_.+b_.*ArcSinh[c_+d_.*x_^2])^n_,x_Symbol] :=
  x*(a+b*ArcSinh[c+d*x^2])^n - 
  2*b*n*Sqrt[2*c*d*x^2+d^2*x^4]*(a+b*ArcSinh[c+d*x^2])^(n-1)/(d*x) + 
  4*b^2*n*(n-1)*Int[(a+b*ArcSinh[c+d*x^2])^(n-2),x] /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,-1] && GtQ[n,1]

2.  ∫(((a+b ArcSinh[c+d (x^2)]))^n)dx  when  (c^2)==-1 ∧ n<0

1:  ∫(1/(a+b ArcSinh[c+d (x^2)]))dx  when  (c^2)==-1

Rule: If  (c^2)==-1, then

∫(1/(a+b ArcSinh[c+d (x^2)]))dx  ⟶  
((x (c Cosh[(a/(2 b))]-Sinh[(a/(2 b))])CoshIntegral[(1/(2 b))(a+b ArcSinh[c+d (x^2)])])/(2 b (Cosh[(1/2) ArcSinh[c+d (x^2)]]+c Sinh[(1/2) ArcSinh[c+d (x^2)]])))+((x (Cosh[(a/(2 b))]-c Sinh[(a/(2 b))]) SinhIntegral[(1/(2 b))(a+b ArcSinh[c+d (x^2)])])/(2 b (Cosh[(1/2) ArcSinh[c+d (x^2)]]+c Sinh[(1/2) ArcSinh[c+d (x^2)]])))

Program code:

Int[1/(a_.+b_.*ArcSinh[c_+d_.*x_^2]),x_Symbol] :=
  x*(c*Cosh[a/(2*b)]-Sinh[a/(2*b)])*CoshIntegral[(a+b*ArcSinh[c+d*x^2])/(2*b)]/
    (2*b*(Cosh[ArcSinh[c+d*x^2]/2]+c*Sinh[(1/2)*ArcSinh[c+d*x^2]])) + 
  x*(Cosh[a/(2*b)]-c*Sinh[a/(2*b)])*SinhIntegral[(a+b*ArcSinh[c+d*x^2])/(2*b)]/
    (2*b*(Cosh[ArcSinh[c+d*x^2]/2]+c*Sinh[(1/2)*ArcSinh[c+d*x^2]])) /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,-1]

2:  ∫(1/(Sqrt[a+b ArcSinh[c+d (x^2)]]))dx  when  (c^2)==-1

Rule: If  (c^2)==-1, then

∫(1/(Sqrt[a+b ArcSinh[c+d (x^2)]]))dx  ⟶  
(((c+1) (Sqrt[(π/2)]) x (Cosh[(a/(2 b))]-Sinh[(a/(2 b))])Erfi[(1/(Sqrt[2 b]))(Sqrt[a+b ArcSinh[c+d (x^2)]])])/(2(Sqrt[b]) (Cosh[(1/2) ArcSinh[c+d (x^2)]]+c Sinh[(1/2) ArcSinh[c+d (x^2)]])))+(((c-1) (Sqrt[(π/2)]) x (Cosh[(a/(2 b))]+Sinh[(a/(2 b))])Erf[(1/(Sqrt[2 b]))(Sqrt[a+b ArcSinh[c+d (x^2)]])])/(2(Sqrt[b]) (Cosh[(1/2) ArcSinh[c+d (x^2)]]+c Sinh[(1/2) ArcSinh[c+d (x^2)]])))

Program code:

Int[1/Sqrt[a_.+b_.*ArcSinh[c_+d_.*x_^2]],x_Symbol] :=
  (c+1)*Sqrt[Pi/2]*x*(Cosh[a/(2*b)]-Sinh[a/(2*b)])*Erfi[Sqrt[a+b*ArcSinh[c+d*x^2]]/Sqrt[2*b]]/
    (2*Sqrt[b]*(Cosh[ArcSinh[c+d*x^2]/2]+c*Sinh[ArcSinh[c+d*x^2]/2])) + 
  (c-1)*Sqrt[Pi/2]*x*(Cosh[a/(2*b)]+Sinh[a/(2*b)])*Erf[Sqrt[a+b*ArcSinh[c+d*x^2]]/Sqrt[2*b]]/
    (2*Sqrt[b]*(Cosh[ArcSinh[c+d*x^2]/2]+c*Sinh[ArcSinh[c+d*x^2]/2])) /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,-1]

3.  ∫(((a+b ArcSinh[c+d (x^2)]))^n)dx  when  (c^2)==-1 ∧ n<-1

1:  ∫(1/(((a+b ArcSinh[c+d (x^2)]))^(3/2)))dx  when  (c^2)==-1

Derivation: Integration by parts

Basis: If  (c^2)==-1, then -((b d x)/((Sqrt[2 c d (x^2)+(d^2) (x^4)]) (((a+b ArcSinh[c+d (x^2)]))^(3/2))))==(∂_x)(1/(Sqrt[a+b ArcSinh[c+d (x^2)]]))

Rule: If  (c^2)==-1, then

∫(1/(((a+b ArcSinh[c+d (x^2)]))^(3/2)))dx  ⟶  -((Sqrt[2 c d (x^2)+(d^2) (x^4)])/(b d x(Sqrt[a+b ArcSinh[c+d (x^2)]])))+(d/b)∫((x^2)/((Sqrt[2 c d (x^2)+(d^2) (x^4)]) (Sqrt[a+b ArcSinh[c+d (x^2)]])))dx

  ⟶  -((Sqrt[2 c d (x^2)+(d^2) (x^4)])/(b d x (Sqrt[a+b ArcSinh[c+d (x^2)]])))-
(((((-(c/b)))^(3/2)) (Sqrt[π]) x (Cosh[(a/(2 b))]-c Sinh[(a/(2 b))]) FresnelC[(Sqrt[-(c/(π b))]) (Sqrt[a+b ArcSinh[c+d (x^2)]])])/(Cosh[(1/2) ArcSinh[c+d (x^2)]]+c Sinh[(1/2) ArcSinh[c+d (x^2)]]))+
(((((-(c/b)))^(3/2))(Sqrt[π]) x (Cosh[(a/(2 b))]+c Sinh[(a/(2 b))]) FresnelS[(Sqrt[-(c/(π b))]) (Sqrt[a+b ArcSinh[c+d (x^2)]])])/(Cosh[(1/2) ArcSinh[c+d (x^2)]]+c Sinh[(1/2) ArcSinh[c+d (x^2)]]))

Program code:

Int[1/(a_.+b_.*ArcSinh[c_+d_.*x_^2])^(3/2),x_Symbol] :=
  -Sqrt[2*c*d*x^2+d^2*x^4]/(b*d*x*Sqrt[a+b*ArcSinh[c+d*x^2]]) - 
  (-c/b)^(3/2)*Sqrt[Pi]*x*(Cosh[a/(2*b)]-c*Sinh[a/(2*b)])*FresnelC[Sqrt[-c/(Pi*b)]*Sqrt[a+b*ArcSinh[c+d*x^2]]]/
    (Cosh[ArcSinh[c+d*x^2]/2]+c*Sinh[ArcSinh[c+d*x^2]/2]) + 
  (-c/b)^(3/2)*Sqrt[Pi]*x*(Cosh[a/(2*b)]+c*Sinh[a/(2*b)])*FresnelS[Sqrt[-c/(Pi*b)]*Sqrt[a+b*ArcSinh[c+d*x^2]]]/
    (Cosh[ArcSinh[c+d*x^2]/2]+c*Sinh[ArcSinh[c+d*x^2]/2]) /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,-1]

2:  ∫(1/(((a+b ArcSinh[c+d (x^2)]))^2))dx  when  (c^2)==-1

Derivation: Integration by parts

Basis: If  (c^2)==-1, then -((2 b d x)/((Sqrt[2 c d (x^2)+(d^2) (x^4)]) (((a+b ArcSinh[c+d (x^2)]))^2)))==(∂_x)(1/(a+b ArcSinh[c+d (x^2)]))

Rule: If  (c^2)==-1, then

∫(1/(((a+b ArcSinh[c+d (x^2)]))^2))dx  ⟶  -((Sqrt[2 c d (x^2)+(d^2) (x^4)])/(2 b d x (a+b ArcSinh[c+d (x^2)])))+(d/(2 b))∫((x^2)/((Sqrt[2 c d (x^2)+(d^2) (x^4)]) (a+b ArcSinh[c+d (x^2)])))dx

  ⟶  -((Sqrt[2 c d (x^2)+(d^2) (x^4)])/(2 b d x (a+b ArcSinh[c+d (x^2)])))+((x (Cosh[(a/(2 b))]-c Sinh[(a/(2 b))])CoshIntegral[(1/(2 b))(a+b ArcSinh[c+d (x^2)])])/(4 (b^2) (Cosh[(1/2) ArcSinh[c+d (x^2)]]+c Sinh[(1/2) ArcSinh[c+d (x^2)]])))+((x (c Cosh[(a/(2 b))]-Sinh[(a/(2 b))]) SinhIntegral[(1/(2 b))(a+b ArcSinh[c+d (x^2)])])/(4 (b^2) (Cosh[(1/2) ArcSinh[c+d (x^2)]]+c Sinh[(1/2) ArcSinh[c+d (x^2)]])))

Program code:

Int[1/(a_.+b_.*ArcSinh[c_+d_.*x_^2])^2,x_Symbol] :=
  -Sqrt[2*c*d*x^2+d^2*x^4]/(2*b*d*x*(a+b*ArcSinh[c+d*x^2])) + 
  x*(Cosh[a/(2*b)]-c*Sinh[a/(2*b)])*CoshIntegral[(a+b*ArcSinh[c+d*x^2])/(2*b)]/
    (4*b^2*(Cosh[ArcSinh[c+d*x^2]/2]+c*Sinh[ArcSinh[c+d*x^2]/2])) + 
  x*(c*Cosh[a/(2*b)]-Sinh[a/(2*b)])*SinhIntegral[(a+b*ArcSinh[c+d*x^2])/(2*b)]/
    (4*b^2*(Cosh[ArcSinh[c+d*x^2]/2]+c*Sinh[ArcSinh[c+d*x^2]/2])) /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,-1]

3:  ∫(((a+b ArcSinh[c+d (x^2)]))^n)dx  when  (c^2)==-1 ∧ n<-1 ∧ n≠-2

Derivation: Inverted integration by parts twice

Rule: If  (c^2)==-1 ∧ n<-1 ∧ n≠-2, then

∫(((a+b ArcSinh[c+d (x^2)]))^n)dx  ⟶  
-((x (((a+b ArcSinh[c+d (x^2)]))^(n+2)))/(4 (b^2) (n+1) (n+2)))+(((Sqrt[2 c d (x^2)+(d^2) (x^4)]) (((a+b ArcSinh[c+d (x^2)]))^(n+1)))/(2 b d (n+1) x))+(1/(4 (b^2) (n+1) (n+2)))∫(((a+b ArcSinh[c+d (x^2)]))^(n+2))dx

Program code:

Int[(a_.+b_.*ArcSinh[c_+d_.*x_^2])^n_,x_Symbol] :=
  -x*(a+b*ArcSinh[c+d*x^2])^(n+2)/(4*b^2*(n+1)*(n+2)) + 
  Sqrt[2*c*d*x^2+d^2*x^4]*(a+b*ArcSinh[c+d*x^2])^(n+1)/(2*b*d*(n+1)*x) + 
  1/(4*b^2*(n+1)*(n+2))*Int[(a+b*ArcSinh[c+d*x^2])^(n+2),x] /;
FreeQ[{a,b,c,d},x] && EqQ[c^2,-1] && LtQ[n,-1] && NeQ[n,-2]

3:  ∫(((ArcSinh[a (x^p)])^n)/x)dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: (((ArcSinh[a (x^p)])^n)/x)==(1/p) Subst[(x^n) Coth[x],x,ArcSinh[a (x^p)]] (∂_x)ArcSinh[a (x^p)]

Rule: If  n∈(SuperPlus[ℤ]), then

∫(((ArcSinh[a (x^p)])^n)/x)dx  ⟶  (1/p) Subst[∫(x^n) Coth[x]dx,x,ArcSinh[a (x^p)]]

Program code:

Int[ArcSinh[a_.*x_^p_]^n_./x_,x_Symbol] :=
  1/p*Subst[Int[x^n*Coth[x],x],x,ArcSinh[a*x^p]] /;
FreeQ[{a,p},x] && IGtQ[n,0]

4:  ∫u ((ArcSinh[(c/(a+b (x^n)))])^m)dx

Derivation:  Algebraic simplification

Basis: ArcSinh[z]==ArcCsch[(1/z)]

Rule:

∫u ((ArcSinh[(c/(a+b (x^n)))])^m)dx  ⟶  ∫u ((ArcCsch[(a/c)+((b (x^n))/c)])^m)dx

Program code:

Int[u_.*ArcSinh[c_./(a_.+b_.*x_^n_.)]^m_.,x_Symbol] :=
  Int[u*ArcCsch[a/c+b*x^n/c]^m,x] /;
FreeQ[{a,b,c,n,m},x]

5:  ∫(((ArcSinh[(Sqrt[-1+b (x^2)])])^n)/(Sqrt[-1+b (x^2)]))dx

Derivation:  Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[b (x^2)])/x)==0

Basis: ((x ((ArcSinh[(Sqrt[-1+b (x^2)])])^n))/((Sqrt[b (x^2)]) (Sqrt[-1+b (x^2)])))==(1/b)Subst[(((ArcSinh[x])^n)/(Sqrt[1+(x^2)])),x,(Sqrt[-1+b (x^2)])] (∂_x)(Sqrt[-1+b (x^2)])

Rule:

∫(((ArcSinh[(Sqrt[-1+b (x^2)])])^n)/(Sqrt[-1+b (x^2)]))dx  ⟶  (( (Sqrt[b (x^2)]))/x) ∫((x ((ArcSinh[(Sqrt[-1+b (x^2)])])^n))/((Sqrt[b (x^2)]) (Sqrt[-1+b (x^2)])))dx
  ⟶  (( (Sqrt[b (x^2)]))/(b x)) Subst[∫(((ArcSinh[x])^n)/(Sqrt[1+(x^2)]))dx,x,(Sqrt[-1+b (x^2)])]

Program code:

Int[ArcSinh[Sqrt[-1+b_.*x_^2]]^n_./Sqrt[-1+b_.*x_^2],x_Symbol] :=
  Sqrt[b*x^2]/(b*x)*Subst[Int[ArcSinh[x]^n/Sqrt[1+x^2],x],x,Sqrt[-1+b*x^2]] /;
FreeQ[{b,n},x]

6.  ∫u (f^(c ((ArcSinh[a+b x])^n)))dx  when  n∈(SuperPlus[ℤ])

1:  ∫(f^(c ((ArcSinh[a+b x])^n)))dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[ArcSinh[a+b x]]==(1/b)Subst[F[x] Cosh[x],x,ArcSinh[a+b x]] (∂_x)ArcSinh[a+b x]

Rule: If  n∈(SuperPlus[ℤ]), then

∫(f^(c ((ArcSinh[a+b x])^n)))dx  ⟶  (1/b)Subst[∫(f^(c (x^n)))Cosh[x]dx,x,ArcSinh[a+b x]]

Program code:

Int[f_^(c_.*ArcSinh[a_.+b_.*x_]^n_.),x_Symbol] :=
  1/b*Subst[Int[f^(c*x^n)*Cosh[x],x],x,ArcSinh[a+b*x]] /;
FreeQ[{a,b,c,f},x] && IGtQ[n,0]

2:  ∫(x^m) (f^(c ((ArcSinh[a+b x])^n)))dx  when  (m|n)∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: F[x,ArcSinh[a+b x]]==(1/b)Subst[F[-(a/b)+((Sinh[x])/b),x] Cosh[x],x,ArcSinh[a+b x]] (∂_x)ArcSinh[a+b x]

Rule: If  (m|n)∈(SuperPlus[ℤ]), then

∫(x^m) (f^(c ((ArcSinh[a+b x])^n)))dx  ⟶  (1/b)Subst[∫(((-(a/b)+((Sinh[x])/b)))^m) (f^(c (x^n)))Cosh[x]dx,x,ArcSinh[a+b x]]

Program code:

Int[x_^m_.*f_^(c_.*ArcSinh[a_.+b_.*x_]^n_.),x_Symbol] :=
  1/b*Subst[Int[(-a/b+Sinh[x]/b)^m*f^(c*x^n)*Cosh[x],x],x,ArcSinh[a+b*x]] /;
FreeQ[{a,b,c,f},x] && IGtQ[m,0] && IGtQ[n,0]

7.  ∫v (a+b ArcSinh[u])dx  when  u is free of inverse functions

1:  ∫ArcSinh[u]dx  when  u is free of inverse functions

Derivation: Integration by parts

Rule: If u is free of inverse functions, then

∫ArcSinh[u]dx  ⟶  x ArcSinh[u]-∫((x (∂_x)u)/(Sqrt[1+(u^2)]))dx

Program code:

Int[ArcSinh[u_],x_Symbol] :=
  x*ArcSinh[u] -
  Int[SimplifyIntegrand[x*D[u,x]/Sqrt[1+u^2],x],x] /;
InverseFunctionFreeQ[u,x] && Not[FunctionOfExponentialQ[u,x]]

2:  ∫(((c+d x))^m)(a+b ArcSinh[u])dx  when  m≠-1 ∧ u is free of inverse functions

Derivation: Integration by parts

Rule: If  m≠-1 ∧ u is free of inverse functions, then

∫(((c+d x))^m)(a+b ArcSinh[u])dx  ⟶  (((((c+d x))^(m+1)) (a+b ArcSinh[u]))/(d(m+1)))-(b/(d(m+1)))∫(((((c+d x))^(m+1)) (∂_x)u)/(Sqrt[1+(u^2)]))dx

Program code:

Int[(c_.+d_.*x_)^m_.*(a_.+b_.*ArcSinh[u_]),x_Symbol] :=
  (c+d*x)^(m+1)*(a+b*ArcSinh[u])/(d*(m+1)) -
  b/(d*(m+1))*Int[SimplifyIntegrand[(c+d*x)^(m+1)*D[u,x]/Sqrt[1+u^2],x],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1] && InverseFunctionFreeQ[u,x] && Not[FunctionOfQ[(c+d*x)^(m+1),u,x]] && Not[FunctionOfExponentialQ[u,x]]

3:  ∫v (a+b ArcSinh[u])dx  when  u and ∫vdx  are free of inverse functions

Derivation: Integration by parts

Rule: If u is free of inverse functions, let  w==∫vdx, if w is free of inverse functions, then

∫v (a+b ArcSinh[u])dx  ⟶  w (a+b ArcSinh[u])-b∫((w (∂_x)u)/(Sqrt[1+(u^2)]))dx

Program code:

Int[v_*(a_.+b_.*ArcSinh[u_]),x_Symbol] :=
  With[{w=IntHide[v,x]},  
  Dist[(a+b*ArcSinh[u]),w,x] - b*Int[SimplifyIntegrand[w*D[u,x]/Sqrt[1+u^2],x],x] /;
 InverseFunctionFreeQ[w,x]] /;
FreeQ[{a,b},x] && InverseFunctionFreeQ[u,x] && Not[MatchQ[v, (c_.+d_.*x)^m_. /; FreeQ[{c,d,m},x]]]

8.  ∫u (e^(n ArcSinh[(Subscript[P, x])]))dx

1:  ∫(e^(n ArcSinh[(Subscript[P, x])]))dx  when  n∈ℤ

Derivation: Algebraic simplification

Basis: (e^(n ArcSinh[z]))==(((z+(Sqrt[1+(z^2)])))^n)

Rule: If  n∈ℤ, then

∫(e^(n ArcSinh[(Subscript[P, x])]))dx  ⟶  ∫((((Subscript[P, x])+(Sqrt[1+((Subscript[P, x])^2)])))^n)dx

Program code:

Int[E^(n_.*ArcSinh[u_]), x_Symbol] :=
  Int[(u+Sqrt[1+u^2])^n,x] /;
IntegerQ[n] && PolyQ[u,x]

2:  ∫(x^m)(e^(n ArcSinh[(Subscript[P, x])]))dx  when  n∈ℤ

Derivation: Algebraic simplification

Basis: (e^(n ArcSinh[z]))==(((z+(Sqrt[1+(z^2)])))^n)

Rule: If  n∈ℤ, then

∫(x^m)(e^(n ArcSinh[(Subscript[P, x])]))dx  ⟶  ∫(x^m)((((Subscript[P, x])+(Sqrt[1+((Subscript[P, x])^2)])))^n)dx

Program code:

Int[x_^m_.*E^(n_.*ArcSinh[u_]), x_Symbol] :=
  Int[x^m*(u+Sqrt[1+u^2])^n,x] /;
RationalQ[m] && IntegerQ[n] && PolyQ[u,x]